En un entorno empresarial, no es inusual imprimir varias copias de un documento. A veces, es beneficioso numerar las copias. Por ejemplo, la primera copia tendría (quizás en un encabezado o pie de página) el texto «Copia 1», la segunda tendría «Copia 2», hasta el número de copias que tenga.

Una opción, por supuesto, es imprimir las copias individuales del documento, haciendo las ediciones en el número de copia entre cada impresión. Esto se vuelve tedioso, muy rápido. Es posible que también desee utilizar un campo de numeración secuencial (como se explica en otros WordTips) y hacer que el número de copias sea igual al que necesita imprimir. Por lo tanto, si tiene que imprimir 25 copias, simplemente puede copiar todo el documento (incluido el campo de numeración secuencial), pasar al final del documento y pegarlo otras 24 veces. Sin embargo, esto lo convierte en un documento general bastante grande y hay formas más fáciles de abordar el problema.

Quizás la solución más fácil a este problema (salvo usar una macro) es simplemente usar las capacidades de combinación de correspondencia de Word. Utilizaría una fuente de datos simple que contuviera los números que desea asignar a cada copia. Luego, coloque el campo de combinación en el lugar apropiado en su documento y ejecute la combinación. Cada copia contendrá el número de copia deseado. El beneficio adicional de usar este enfoque es que puede usar información adicional con su combinación, según lo requieran las necesidades. Por ejemplo, si cada copia del documento se asignó a una persona en particular, simplemente puede agregar otro campo de datos a su fuente de datos que contenga el nombre de la persona que recibirá la copia. Luego, también puede imprimir el nombre de esa persona en cada documento combinado.

Si lo prefiere, puede utilizar una macro para imprimir sus copias numeradas.

Por ejemplo, la siguiente macro le pregunta cuántas copias desea imprimir, junto con el número de copia inicial que debe usar. (Esto es muy útil si imprime 25 copias y luego alguien le pide que imprima un segundo lote de 10, numerados del 26 al 35). La macro también almacena el número de la última copia entre sesiones, de modo que se usa como predeterminado la próxima vez que ejecute la macro.

Public Sub PrintNumberedCopies1()

Dim varItem As Variable     Dim bExists As Boolean     Dim lCopiesToPrint As Long     Dim lCounter As Long     Dim lCopyNumFrom As Long

' ensure our doc variable exists     bExists = False     For Each varItem In ActiveDocument.Variables         If varItem.Name = "CopyNum" Then             bExists = True             Exit For         End If     Next varItem

' initialize document variable if doesn't exist     If Not bExists Then         ActiveDocument.Variables.Add _             Name:="CopyNum", Value:=0     End If

' ask how many to print     lCopiesToPrint = InputBox( _         Prompt:="How many copies?", _         Title:="Print And Number Copies", _         Default:="1")



' ask where to start numbering     lCopyNumFrom = CLng(InputBox( _         Prompt:="Number at which to start numbering copies?", _         Title:="Print And Number Copies", _         Default:=CStr(ActiveDocument.Variables("CopyNum") + 1)))



' loop through the print-write-print cycle     For lCounter = 0 To lCopiesToPrint - 1         ' update the document variable         ActiveDocument.Variables("CopyNum") = _             lCopyNumFrom + lCounter         ' print this numbered copy         ActiveDocument.PrintOut Copies:=1     Next lCounter End Sub

Para utilizar esta macro, hay otras dos cosas que debe hacer.

Primero, debe indicar en su documento dónde desea que aparezca el número de copia. En el punto donde debería imprimirse, simplemente inserte el siguiente campo (recuerde que inserta las llaves de campo presionando Ctrl + F9):

{ DOCVARIABLE "CopyNum" }

Lo segundo que debe hacer es asegurarse de que Word esté configurado para que actualice los campos cuando se imprima. Ahora, cuando ejecuta la macro, se le pregunta cuántas copias desea imprimir y qué número inicial utilizar. La variable del documento se actualiza y se imprime una única copia del documento. Estos pasos se repiten el número de veces que eligió imprimir.

Desafortunadamente, esta solución de macros no funcionará en todas las versiones de Word. Por ejemplo, si coloca el campo DOCVARIABLE en el encabezado de un documento de Word 97 y luego imprime el documento, Word se bloqueará de inmediato.

Cómo evitar esto? Simplemente use un enfoque diferente. (Word no es nada, si no es flexible). La siguiente macro funciona en todas las versiones modernas de Word. Es una variación del anterior que se basa en el uso de propiedades de documento personalizadas en lugar de variables de documento.

Public Sub PrintNumberedCopies2()

Dim varItem As DocumentProperty     Dim bExists As Boolean     Dim lCopiesToPrint As Long     Dim lCounter As Long     Dim lCopyNumFrom As Long

' ensure our doc variable exists     bExists = False     For Each varItem In ActiveDocument.CustomDocumentProperties         If varItem.Name = "CopyNum" Then             bExists = True             Exit For         End If     Next varItem

' initialize document variable if doesn't exist     If Not bExists Then         ActiveDocument.CustomDocumentProperties.Add _             Name:="CopyNum", LinkToContent:=False, _             Type:=msoPropertyTypeNumber, Value:=0     End If

' ask how many to print     lCopiesToPrint = InputBox( _         Prompt:="How many copies?", _         Title:="Print And Number Copies", _         Default:="1")



' ask where to start numbering     lCopyNumFrom = CLng(InputBox( _         Prompt:="Number at which to start numbering copies?", _         Title:="Print And Number Copies", _         Default:=CStr(ActiveDocument.CustomDocumentProperties("CopyNum") + 1)))



' loop through the print-write-print cycle     For lCounter = 0 To lCopiesToPrint - 1         ' update the document variable         ActiveDocument.CustomDocumentProperties("CopyNum") = _             lCopyNumFrom + lCounter         ' print this numbered copy         ActiveDocument.PrintOut Copies:=1     Next lCounter End Sub

Para utilizar esta macro, hay otras dos cosas que debe hacer.

Primero, debe indicar en su documento dónde desea que aparezca el número de copia. En el punto donde debería imprimirse, simplemente inserte el siguiente campo (recuerde que inserta las llaves de campo presionando Ctrl + F9):

{ DOCPROPERTY "CopyNum" }

Cuando inserta el campo por primera vez, puede ver un mensaje de error devuelto por el campo, como «¡Error! Nombre de propiedad del documento desconocido». No se preocupe; esto desaparecerá y será reemplazado por el número de copia adecuado después de ejecutar la macro.

Lo segundo que debe hacer es asegurarse de que Word esté configurado para que actualice los campos cuando se imprima. Ahora, cuando ejecuta la macro, se le pregunta cuántas copias desea imprimir y qué número inicial utilizar. La variable del documento se actualiza y se imprime una única copia del documento. Estos pasos se repiten el número de veces que eligió imprimir.

_Nota: _

Si desea saber cómo usar las macros descritas en esta página (o en cualquier otra página de los sitios WordTips), he preparado una página especial que incluye información útil.

link: / wordribbon-WordTipsMacros [Haga clic aquí para abrir esa página especial en una nueva pestaña del navegador].

WordTips es su fuente de formación rentable en Microsoft Word.

(Microsoft Word es el software de procesamiento de texto más popular del mundo). Este consejo (844) se aplica a Microsoft Word 97, 2000, 2002 y 2003. Puede encontrar una versión de este consejo para la interfaz de cinta de Word (Word 2007 y más tarde) aquí:

link: / wordribbon-Printing_Copy_Numbers [Impresión de números de copia].