每张纸的UsedRange复制到Microsoft Excel中使用VBA一张
| 如果要将每个工作表的已用范围复制到母版表中，则应阅读本文。我们将使用VBA代码复制每个工作表中的数据，然后将其粘贴到另一个工作表中而不会被覆盖。
宏将在工作簿中添加一个名称为Master的工作表，并将该工作表中工作表中每个工作表的单元格复制。
第一个宏进行普通复制，第二个宏复制“值”。宏的子菜单使用以下功能；没有这些功能，宏将无法正常工作。
|以下是Sheet1和Sheet2的数据快照：
我们需要按照以下步骤启动VB编辑器：
单击“开发人员”选项卡。从“代码”组中，选择“ Visual Basic”
-
将以下代码复制到标准模块中
Sub CopyUsedRange()
Dim sh As Worksheet
Dim DestSh As Worksheet
Dim Last As Long
If SheetExists("Master") = True Then
MsgBox "The sheet Master already exist"
Exit Sub
End If
Application.ScreenUpdating = False
Set DestSh = Worksheets.Add
DestSh.Name = "Master"
For Each sh In ThisWorkbook.Worksheets
If sh.Name <> DestSh.Name Then
If sh.UsedRange.Count > 1 Then
Last = LastRow(DestSh)
sh.UsedRange.Copy DestSh.Cells(Last + 1, 1)
End If
End If
Next
Application.ScreenUpdating = True
End Sub
Sub CopyUsedRangeValues()
Dim sh As Worksheet
Dim DestSh As Worksheet
Dim Last As Long
If SheetExists("Master") = True Then
MsgBox "The sheet Master already exist"
Exit Sub
End If
Application.ScreenUpdating = False
Set DestSh = Worksheets.Add
DestSh.Name = "Master"
For Each sh In ThisWorkbook.Worksheets
If sh.Name <> DestSh.Name Then
If sh.UsedRange.Count > 1 Then
Last = LastRow(DestSh)
With sh.UsedRange
DestSh.Cells(Last + 1, 1).Resize(.Rows.Count, _
.Columns.Count).Value = .Value
End With
End If
End If
Next
Application.ScreenUpdating = True
End Sub
Function LastRow(sh As Worksheet)
On Error Resume Next
LastRow = sh.Cells.Find(What:="*", _
After:=sh.Range("A1"), _
Lookat:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Row
On Error GoTo 0
End Function
Function Lastcol(sh As Worksheet)
On Error Resume Next
Lastcol = sh.Cells.Find(What:="*", _
After:=sh.Range("A1"), _
Lookat:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByColumns, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Column
On Error GoTo 0
End Function
Function SheetExists(SName As String, _
Optional ByVal WB As Workbook) As Boolean
On Error Resume Next
If WB Is Nothing Then Set WB = ThisWorkbook
SheetExists = CBool(Len(Sheets(SName).Name))
End Function
现在，宏代码已设置；我们将运行宏“ CopyUsedRange”，它将插入新的工作表“ Master”并复制每张工作表中的数据。
结论：*从多张纸复制数据是一项手动任务；然而;使用上面的代码，我们只需单击一个宏即可合并数据。
如果您喜欢我们的博客，请在Facebook上与您的朋友分享。您也可以在Twitter和Facebook上关注我们。
我们很高兴收到您的来信，请让我们知道我们如何改进，补充或创新我们的工作，并为您做得更好。写信给我们[email protected]