열고 통합 문서를 저장하기위한 대화 상자를 사용하여

Posted on: 2020年11月12日 2020年11月12日
Tags: files-workbook-and-worksheets-in-vba

우리는 이미 VBA에서 Excel 파일을 열거 나 저장하는 방법을 알고 있습니다. Workbook 개체의 Open 및 SaveAs 메서드를 사용하기 만하면됩니다. 그러나 파일 경로를 하드 코딩해야합니다. 그러나 대부분의 경우 최종 사용자가 GUI를 사용하여 파일을 선택하거나 파일 열기 또는 다른 이름으로 저장 대화 상자라고 말하면 사용자가 시각적으로 쉽게 파일 위치를 선택할 수 있습니다.

이 기사에서는 통합 문서 열기 대화 상자를 표시하고 대화 상자로 저장하는 데 사용되는 코드를 다룹니다.

다운로드 할 수있는 통합 문서를 첨부했습니다. 이 기사에 첨부 된 통합 문서에는 3 개의 매크로 === 파일 열기 대화 상자를 사용하여 파일을 여는 VBA 코드이 코드에서는 Application의 GetOpenFilename 메서드를 사용합니다. GetOpenFilename 메서드의 구문은 다음과 같습니다.

_Application.GetOpenFilename ([FileFilter], [FilterIndex], [Title], [ButtonText], [MultiSelect]) _ [FileFilter] : 선택한 폴더에 한 종류의 파일 만 표시하도록 정의 할 수 있습니다. “Excel-Files, .xlsx, .xls, * .xlsm”등을 쓰면

그러면 파일 열기 대화 상자의 폴더에서 Excel 파일 만 표시됩니다.

[FilterIndex] : * 사용할 파일 필터의 수입니다.

[제목] : 대화 상자의 제목입니다.

[ButtonText] : * 버튼 텍스트를 지정합니다. 중요하지 않습니다.

[MultiSelect] : 부울 변수입니다. True 또는 1로 설정하면 하나 이상의 파일을 선택할 수 있습니다. false로 설정하면 하나의 파일 만 선택할 수 있습니다.

이론은 충분합니다. 주문을 좀 해보자.

한 번에 하나의 파일을 여는 VBA 코드

Option Explicit

Sub OpenOneFile()

Dim FileName As Variant

'Displaying the open file dialog box

FileName = Application.GetOpenFilename("Excel-files,*.xls", _

1, "Select One File To Open", , False)

'User didn't select a file

If TypeName(FileName) = "Boolean" Then Exit Sub

'Open the workbook

Workbooks.Open FileName

End Sub

ArrowOpeningSingle

어떻게 작동합니까?

이 코드 세그먼트를 실행하면 응용 프로그램 개체에 대한 GetOpenFilename 메서드가 파일 열기 대화 상자를 엽니 다. 대화 상자의 제목은 코드에서 정의한 “열려면 하나의 파일 선택”이됩니다.

파일을 선택하면 Worbook.Open 코드가 실행되고 파일이 열립니다. 파일을 선택하지 않으면 Workbook.Open 코드를 실행하지 않고 서브가 종료됩니다.

한 번에 하나 이상의 파일을 여는 VBA 코드이 코드 세그먼트는 파일 열기 대화 상자를 열지 만 한 번에 둘 이상의 파일을 선택할 수 있습니다.

Sub OpenMultipleFiles()

Dim FileName As Variant, f As Integer

'Displaying the open file dialog box

FileName = Application.GetOpenFilename("Excel-files,*.xlsx", _

1, "Select One Or More Files To Open", , True)

'User didn't select a file

If TypeName(FileName) = "Boolean" Then Exit Sub

'Open all the workbooks selected by user

For f = 1 To UBound(FileName)

Workbooks.Open FileName(f)

Next f

End Sub

여기에서는 다중 선택 변수를 True로 설정했습니다. 이렇게하면 파일을 여러 개 선택할 수 있습니다.

ArrowOpeningMultiple

다른 이름으로 저장 대화 상자를 여는 VBA 코드 다른 이름으로 저장 대화 상자를 열려면 Application 개체의 GetSaveAsFilename 메서드를 사용합니다. 메서드 구문은 다음과 같습니다.

_Application.GetSaveAsFilename ([InitialFileName], [FileFilter], [FilterIndex], [Title], [ButtonText]) _ [InitialFileName] : * 초기 파일 이름입니다. 파일을 저장하는 동안 이름을 변경하지 않으면 파일이이 이름으로 저장됩니다.

[FileFilter] : 선택한 폴더에 한 종류의 파일 만 표시하도록 정의 할 수 있습니다. “Excel-Files, .xlsx, .xls, * .xlsm”등을 쓰면

그러면 파일 열기 대화 상자의 폴더에서 Excel 파일 만 표시됩니다.

[FilterIndex] : 파일의 필터 인덱스.

[Title] : * 대화 상자의 제목입니다.

[ButtonText] : * Mac 시스템에서 버튼 이름을 변경하는 데 사용됩니다.

아래 코드를 따르세요

Sub SaveFile()

Dim FileName As Variant

'Displaying the saveas dialog box

FileName = Application.GetSaveAsFilename("MyFileName.xls", _

"Excel files,*.xls", 1, "Select your folder and filename")

'User didn't save a file

If TypeName(FileName) = "Boolean" Then Exit Sub

'Save the workbook

ActiveWorkbook.SaveAs FileName

End Sub

SaveFile 매크로는 Application 개체의 GetSaveAsFilename 메서드를 사용하여 다른 이름으로 저장 대화 상자를 열고 파일 이름을 할당하고 통합 문서를 저장할 위치를 선택합니다.

ArrowSavingWorkbook

예, 이것이 대화 상자를 사용하여 VBA를 사용하여 파일을 열고 저장할 수있는 방법입니다. 도움이 되었기를 바랍니다. 이 기사 또는 다른 VBA 주제에 대해 의문이 있으시면 아래 의견 섹션에서 질문하십시오.