Privates Profil Strings mit INI-Dateien mit VBA in Microsoft Excel
Private Profilzeichenfolgen werden häufig verwendet, um benutzerspezifische Informationen außerhalb der Anwendung / des Dokuments für die spätere Verwendung zu speichern.
Sie können beispielsweise Informationen über den neuesten Inhalt in einem Dialogfeld / UserForm speichern, wie oft eine Arbeitsmappe geöffnet wurde oder die zuletzt verwendete Rechnungsnummer für eine Rechnungsvorlage.
Die Informationen können in einer INI-Datei entweder auf der lokalen Festplatte oder in einem freigegebenen Netzwerkordner gespeichert werden.
Eine INI-Datei ist eine gewöhnliche Textdatei und der Inhalt könnte ungefähr so aussehen:
Nachname = Doe Vorname = John Birthdate = 1.1.1960 UniqueNumber = 123456 Private Profilzeichenfolgen für jeden Benutzer können auch in der Registrierung gespeichert werden.
Excel verfügt über keine integrierten Funktionen zum Lesen und Schreiben in INI-Dateien wie Word (System.PrivateProfileString). Daher benötigen Sie einige API-Funktionen, um dies auf einfache Weise zu tun.
Hier sind die Beispielmakros zum Schreiben und Lesen in eine INI-Datei mit privaten Profilzeichenfolgen.
Const IniFileName As String = „C: \ FolderName \ UserInfo.ini“
‚den Pfad und den Dateinamen zu der Datei, die die Informationen enthält, die Sie lesen / schreiben möchten
Private Declare Function GetPrivateProfileStringA Lib _
"Kernel32" (ByVal strSection As String, _
ByVal strKey As String, ByVal strDefault As String, _
ByVal strReturnedString As String, _
ByVal lngSize As Long, ByVal strFileNameName As String) As Long
Private Declare Function WritePrivateProfileStringA Lib _
"Kernel32" (ByVal strSection As String, _
ByVal strKey As String, ByVal strString As String, _
ByVal strFileNameName As String) As Long
Private Function WritePrivateProfileString32(ByVal strFileName As String, _
ByVal strSection As String, ByVal strKey As String, _
ByVal strValue As String) As Boolean
Dim lngValid As Long
On Error Resume Next
lngValid = WritePrivateProfileStringA(strSection, strKey, _
strValue, strFileName)
If lngValid > 0 Then WritePrivateProfileString32 = True
On Error GoTo 0
End Function
Private Function GetPrivateProfileString32(ByVal strFileName As String, _
ByVal strSection As String, ByVal strKey As String, _
Optional strDefault) As String
Dim strReturnString As String, lngSize As Long, lngValid As Long
On Error Resume Next
If IsMissing(strDefault) Then strDefault = ""
strReturnString = Space(1024)
lngSize = Len(strReturnString)
lngValid = GetPrivateProfileStringA(strSection, strKey, _
strDefault, strReturnString, lngSize, strFileName)
GetPrivateProfileString32 = Left(strReturnString, lngValid)
On Error GoTo 0
End Function
' the examples below assumes that the range B3:B5 in the active sheet contains
' information about Lastname, Firstname and Birthdate
Sub WriteUserInfo()
' saves information in the file IniFileName
If Not WritePrivateProfileString32(IniFileName, "PERSONAL", _
"Lastname", Range("B3").Value) Then
MsgBox "Not able to save user info in " & IniFileName, _
vbExclamation, "Folder does not exist!"
Exit Sub
End If
WritePrivateProfileString32 IniFileName, "PERSONAL", _
"Lastname", Range("B3").Value
WritePrivateProfileString32 IniFileName, "PERSONAL", _
"Firstname", Range("B4").Value
WritePrivateProfileString32 IniFileName, "PERSONAL", _
"Birthdate", Range("B5").Value
End Sub
Sub ReadUserInfo()
' reads information from the file IniFileName
If Dir(IniFileName) = "" Then Exit Sub
Range("B3").Formula = GetPrivateProfileString32(IniFileName, _
"PERSONAL", "Lastname")
Range("B4").Formula = GetPrivateProfileString32(IniFileName, _
"PERSONAL", "Firstname")
Range("B5").Formula = GetPrivateProfileString32(IniFileName, _
"PERSONAL", "Birthdate")
End Sub
' the example below assumes that the range D4 in the active sheet contains
' information about the unique number
Sub GetNewUniqueNumber()
Dim UniqueNumber As Long
If Dir(IniFileName) = "" Then Exit Sub
UniqueNumber = 0
On Error Resume Next
UniqueNumber = CLng(GetPrivateProfileString32(IniFileName, _
"PERSONAL", "UniqueNumber"))
On Error GoTo 0
Range("D4").Formula = UniqueNumber + 1
If Not WritePrivateProfileString32(IniFileName, "PERSONAL", _
"UniqueNumber", Range("D4").Value) Then
MsgBox "Not able to save user info in " & IniFileName, _
vbExclamation, "Folder does not exist!"
Exit Sub
End If
End Sub